| # AM_CONDITIONAL -*- Autoconf -*- |
| |
| # Copyright (C) 1997, 2000, 2001, 2003, 2004, 2005, 2006, 2008 |
| # Free Software Foundation, Inc. |
| # |
| # This file is free software; the Free Software Foundation |
| # gives unlimited permission to copy and/or distribute it, |
| # with or without modifications, as long as this notice is preserved. |
| |
| # serial 9 |
| |
| # AM_CONDITIONAL(NAME, SHELL-CONDITION) |
| # ------------------------------------- |
| # Define a conditional. |
| AC_DEFUN([AM_CONDITIONAL], |
| [AC_PREREQ(2.52)dnl |
| ifelse([$1], [TRUE], [AC_FATAL([$0: invalid condition: $1])], |
| [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl |
| AC_SUBST([$1_TRUE])dnl |
| AC_SUBST([$1_FALSE])dnl |
| _AM_SUBST_NOTMAKE([$1_TRUE])dnl |
| _AM_SUBST_NOTMAKE([$1_FALSE])dnl |
| m4_define([_AM_COND_VALUE_$1], [$2])dnl |
| if $2; then |
| $1_TRUE= |
| $1_FALSE='#' |
| else |
| $1_TRUE='#' |
| $1_FALSE= |
| fi |
| AC_CONFIG_COMMANDS_PRE( |
| [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then |
| AC_MSG_ERROR([[conditional "$1" was never defined. |
| Usually this means the macro was only invoked conditionally.]]) |
| fi])]) |
